public OnPluginStart() {
    RegConsoleCmd("test", test);
}

public Action:test(client, args) {
    if (client > 0 && args < 1) {
        ShowMyPanel(client);
    }
    return Plugin_Handled;
}

ShowMyPanel(client)
{
    new Handle:panel = CreatePanel();
    SetPanelTitle(panel, "Животные:\n ");
    DrawPanelItem(panel, "Кот");
    DrawPanelText(panel, "Носорог");
    DrawPanelItem(panel, "Собак");
    DrawPanelItem(panel, "Хамелеон");
    DrawPanelItem(panel, "Тигр \n ");
    DrawPanelItem(panel, "Выход");
    SendPanelToClient(panel, client, Select_Panel, 0);
    CloseHandle(panel);
    ClientCommand(client, "playgamesound items/nvg_off.wav");
}

public Select_Panel(Handle:panel, MenuAction:action, client, option) {
    if (action == MenuAction_Select) {
        PrintToChat(client, "Номер выбранной опции: %d", option);
        if (option < 5) {
            ShowMyPanel(client);
        }
    }
}

hStyle (стиль меню):

MenuStyle_Default = 0 // The "default" menu style for the mod
MenuStyle_Valve = 1 // The Valve provided menu style (Used on HL2DM)
MenuStyle_Radio = 2 // The simpler menu style commonly used on CS:S

Тип опции (style):
ITEMDRAW_DEFAULT - используется по умолчанию
ITEMDRAW_DISABLED - опцию нельзя выбрать + текст становится белым)
ITEMDRAW_RAWLINE - Item should be a raw line, without a slot
ITEMDRAW_NOTEXT - No text should be drawn
ITEMDRAW_SPACER - Item should be drawn as a spacer, if possible
ITEMDRAW_IGNORE - Item should be completely ignored (rawline + notext)
ITEMDRAW_CONTROL - Item is control text (back/next/exit)

public xzFuncName(Handle:panel, MenuAction:action, param1, param2)
{
    // если надо ловить момент выбора опций:
    if (action == MenuAction_Select)
    {
        // ваш код
    }
}

MenuAction_Select - игрок выбрал опцию (param1 = client, param2 = номер опции)
MenuAction_Cancel - игрок закрыл меню (param1 = client, param2 = reason)
MenuAction_End - меню стало неактивным (param1 = reason)
и др.

MenuCancel_Disconnected - игрок покинул сервер
MenuCancel_Interrupted - меню закрылось, так как открылось новое
MenuCancel_Exit - игрок нажал "выход"
MenuCancel_NoDisplay - меню не может быть отображено клиенту
MenuCancel_Timeout - время отображения меню истекло
MenuCancel_ExitBack - клиент выбрал "exit back (выйти обратно)" на одной из страниц

MenuEnd_Selected - выбрана опция в меню
MenuEnd_VotingDone - голосование было завершено
MenuEnd_VotingCancelled - голосование отменено
MenuEnd_Cancelled - меню было отменено (param2 = reason)
MenuEnd_Exit - игрок нажал "exit (выход)"
MenuEnd_ExitBack - нажал "back"

public OnPluginStart() {
    RegConsoleCmd("test", test);
}

public Action:test(client, args) {
    if (client > 0 && args < 1) {
        ShowMyMenu(client);
    }
    return Plugin_Handled;
}

ShowMyMenu(client)
{
    new Handle:menu = CreateMenu(Select_Menu);
    SetMenuTitle(menu, "Выберите Игрока:\n ");
    decl String:userid[16], String:name[32];
    for (new i = 1; i <= MaxClients; i++) {
        if (IsClientInGame(i))
        {
            IntToString(GetClientUserId(i), userid, sizeof(userid));
            GetClientName(i, name, sizeof(name));
            AddMenuItem(menu, userid, name);
        }
    }
    DisplayMenu(menu, client, 0);
}

public Select_Menu(Handle:menu, MenuAction:action, client, option)
{
    if (action == MenuAction_End)
    {
        // Если меню стало неактивным, обязательно уничтожьте его.
        // Исключение:    
        // Меню глобальное и оно еще вам нужно.
        CloseHandle(menu);
        return;
    }

    if (action != MenuAction_Select) {
        return;
    }

    decl String:userid[16];
    GetMenuItem(menu, option, userid, sizeof(userid));

    new target = GetClientOfUserId(StringToInt(userid));
    if (target > 0)
    {
        PrintToChat(client, "Индекс игрока: %d | id: %s", target, userid);
        new cash = GetEntProp(target, Prop_Send, "m_iAccount") + 1;
        if (cash < 16001)
        {
            SetEntProp(target, Prop_Send, "m_iAccount", cash);
            PrintToChatAll("Игроку < %N > добавлен $1", target);
        }
        else {
            PrintToChat(client, "У него $16000");
        }
    }
    else {
        PrintToChat(client, "Игрок не найден (вышел с сервера)");
    }
    ShowMyMenu(client);
}

DisplayMenuAtItem(menu, client, GetMenuSelectionPosition(), 0);