#include <cstrike>

#pragma semicolon 1
#pragma newdecls required

public Plugin myinfo =
{
    name    = "Weapon Limit [awp 5x5]",
    version    = "1.0.1",
    author    = "wS",
};

/////

// https://world-source.ru/hueco_mundo/weapon_limit_config.zip
#undef REQUIRE_PLUGIN
#include <weapon_limit>

static const char g_sWeaponLimitLib[] = "WeaponLimitLib";
bool    g_bWeaponLimitLib = false;

public void OnLibraryAdded(const char[] name) {
    if(!g_bWeaponLimitLib && !strcmp(name, g_sWeaponLimitLib)) {
        g_bWeaponLimitLib = true;
        UpdateLimit();
    }
}
public void OnLibraryRemoved(const char[] name) {
    if (g_bWeaponLimitLib && !strcmp(name, g_sWeaponLimitLib)) {
        g_bWeaponLimitLib = false;
    }
}

/////

public void OnPluginStart()
{
    HookEvent("round_start", Event_round_start, EventHookMode_PostNoCopy);
}

static void Event_round_start(Event event, const char[] name, bool dontBroadcast)
{
    if (g_bWeaponLimitLib) {
        UpdateLimit();
    }
}

static void UpdateLimit()
{
    /////
        
    // {A , B}. Если есть A TT и A CT, то лимит awp B.".
    static const int awp_limit[][] =
    {
        {5 , 1},
        {10, 2},
        {15, 3},
        {20, 4},
        {25, 5},
        {30, 6}
    };
        
    // Если ни одно условие (awp_limit) не выполнено, какой установить лимит?
    int awp_limit_default = 0;
        
    /////
        
    int tt = 0;
    int ct = 0;
        
    for (int client = 0; ++client <= MaxClients;) {
        if (IsClientInGame(client)) {
            switch (GetClientTeam(client)) {
                case 2: {
                    tt++;
                }
                case 3: {
                    ct++;
                }
            }
        }
    }
        
    for (int i = sizeof(awp_limit) - 1; i > -1; i--) {
        if ((tt >= awp_limit[i][0]) && (ct >= awp_limit[i][0])) {
            WL_SetWeaponLimit(CSWeapon_AWP, awp_limit[i][1], awp_limit[i][1]);
            return;
        }
    }
        
    WL_SetWeaponLimit(CSWeapon_AWP, /* tt_limit */awp_limit_default, /* ct_limit */awp_limit_default);
}