[SkydiveX]

Wahey! Look what I have stumbled upon.
A Revolution Possibly.
I was bored so after scurrying old sourcemod forums I have managed to find some code that PERFECTLY mimics viewmodel and worldmodel replacement.

Spoiler

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>

#pragma semicolon 1

#define EF_NODRAW 32

new CustomModel1;
new CustomModel2;

new CustomWorldModel1;
new CustomWorldModel2;

new bool:SpawnCheck[MAXPLAYERS+1];
new ClientVM[MAXPLAYERS+1][2];
new bool:IsCustom[MAXPLAYERS+1];

public OnPluginStart()
{
    HookEvent("player_death", Event_PlayerDeath);
    HookEvent("player_spawn", Event_PlayerSpawn);
    
    for (new client = 1; client <= MaxClients; client++) 
    { 
        if (IsClientInGame(client)) 
        {
            SDKHook(client, SDKHook_PostThinkPost, OnPostThinkPost);
            
            //find both of the clients viewmodels
            ClientVM[client][0] = GetEntPropEnt(client, Prop_Send, "m_hViewModel");
            
            new PVM = -1;
            while ((PVM = FindEntityByClassname(PVM, "predicted_viewmodel")) != -1)
            {
                if (GetEntPropEnt(PVM, Prop_Send, "m_hOwner") == client)
                {
                    if (GetEntProp(PVM, Prop_Send, "m_nViewModelIndex") == 1)
                    {
                        ClientVM[client][1] = PVM;
                        break;
                    }
                }
            }
        } 
    }
}

public OnMapStart()
{
    CustomModel1 = PrecacheModel("models/Weapons/v_smg_tmp.mdl");
    CustomModel2 = PrecacheModel("models/Weapons/v_smg_p90.mdl");
    
    CustomWorldModel1 = PrecacheModel("models/Weapons/w_smg_tmp.mdl");
    CustomWorldModel2 = PrecacheModel("models/Weapons/w_smg_p90.mdl");    
}

public OnClientPutInServer(client)
{
    SDKHook(client, SDKHook_PostThinkPost, OnPostThinkPost);
    //WorldModel
    SDKHook(client, SDKHook_WeaponSwitch, WeaponHook);
    SDKHook(client, SDKHook_WeaponEquip, WeaponHook);
    
    
}

public OnEntityCreated(entity, const String:classname[])
{
    if (StrEqual(classname, "predicted_viewmodel", false))
    {
        SDKHook(entity, SDKHook_Spawn, OnEntitySpawned);
    }
}

//find both of the clients viewmodels
public OnEntitySpawned(entity)
{
    new Owner = GetEntPropEnt(entity, Prop_Send, "m_hOwner");
    if ((Owner > 0) && (Owner <= MaxClients))
    {
        if (GetEntProp(entity, Prop_Send, "m_nViewModelIndex") == 0)
        {
            ClientVM[Owner][0] = entity;
        }
        else if (GetEntProp(entity, Prop_Send, "m_nViewModelIndex") == 1)
        {
            ClientVM[Owner][1] = entity;
        }
    }
}

public OnPostThinkPost(client)
{
    static OldWeapon[MAXPLAYERS + 1];
    static OldSequence[MAXPLAYERS + 1];
    static Float:OldCycle[MAXPLAYERS + 1];
    
    decl String:ClassName[30];
    new WeaponIndex;
    
    //handle spectators
    if (!IsPlayerAlive(client))
    {
        new spec = GetEntPropEnt(client, Prop_Send, "m_hObserverTarget");
        if (spec != -1)
        {
            WeaponIndex = GetEntPropEnt(spec, Prop_Send, "m_hActiveWeapon");
            GetEdictClassname(WeaponIndex, ClassName, sizeof(ClassName));
            if (StrEqual("weapon_mp5navy", ClassName, false))
            {
                SetEntProp(ClientVM[client][1], Prop_Send, "m_nModelIndex", CustomModel1);
            }
            else if (StrEqual("weapon_ump45", ClassName, false))
            {
                SetEntProp(ClientVM[client][1], Prop_Send, "m_nModelIndex", CustomModel2);
            }
        }
        
        return;
    }
    
    WeaponIndex = GetEntPropEnt(client, Prop_Send, "m_hActiveWeapon");
    new Sequence = GetEntProp(ClientVM[client][0], Prop_Send, "m_nSequence");
    new Float:Cycle = GetEntPropFloat(ClientVM[client][0], Prop_Data, "m_flCycle");
    
    if (WeaponIndex <= 0)
    {
        new EntEffects = GetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects");
        EntEffects |= EF_NODRAW;
        SetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects", EntEffects);
        
        IsCustom[client] = false;
            
        OldWeapon[client] = WeaponIndex;
        OldSequence[client] = Sequence;
        OldCycle[client] = Cycle;
        
        return;
    }
    
    //just stuck the weapon switching in here aswell instead of a separate hook
    if (WeaponIndex != OldWeapon[client])
    {
        GetEdictClassname(WeaponIndex, ClassName, sizeof(ClassName));
        if (StrEqual("weapon_mp5navy", ClassName, false))
        {
            //hide viewmodel
            new EntEffects = GetEntProp(ClientVM[client][0], Prop_Send, "m_fEffects");
            EntEffects |= EF_NODRAW;
            SetEntProp(ClientVM[client][0], Prop_Send, "m_fEffects", EntEffects);
            //unhide unused viewmodel
            EntEffects = GetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects");
            EntEffects &= ~EF_NODRAW;
            SetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects", EntEffects);
            
            //set model and copy over props from viewmodel to used viewmodel
            SetEntProp(ClientVM[client][1], Prop_Send, "m_nModelIndex", CustomModel1);
            SetEntPropEnt(ClientVM[client][1], Prop_Send, "m_hWeapon", GetEntPropEnt(ClientVM[client][0], Prop_Send, "m_hWeapon"));
            
            SetEntProp(ClientVM[client][1], Prop_Send, "m_nSequence", GetEntProp(ClientVM[client][0], Prop_Send, "m_nSequence"));
            SetEntPropFloat(ClientVM[client][1], Prop_Send, "m_flPlaybackRate", GetEntPropFloat(ClientVM[client][0], Prop_Send, "m_flPlaybackRate"));
            
            IsCustom[client] = true;
        }
        else if (StrEqual("weapon_ump45", ClassName, false))
        {
            new EntEffects = GetEntProp(ClientVM[client][0], Prop_Send, "m_fEffects");
            EntEffects |= EF_NODRAW;
            SetEntProp(ClientVM[client][0], Prop_Send, "m_fEffects", EntEffects);
            
            EntEffects = GetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects");
            EntEffects &= ~EF_NODRAW;
            SetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects", EntEffects);
            
            SetEntProp(ClientVM[client][1], Prop_Send, "m_nModelIndex", CustomModel2);
            SetEntPropEnt(ClientVM[client][1], Prop_Send, "m_hWeapon", GetEntPropEnt(ClientVM[client][0], Prop_Send, "m_hWeapon"));
            
            SetEntProp(ClientVM[client][1], Prop_Send, "m_nSequence", GetEntProp(ClientVM[client][0], Prop_Send, "m_nSequence"));
            SetEntPropFloat(ClientVM[client][1], Prop_Send, "m_flPlaybackRate", GetEntPropFloat(ClientVM[client][0], Prop_Send, "m_flPlaybackRate"));
            
            IsCustom[client] = true;
        }
        else
        {
            //hide unused viewmodel if the current weapon isn't using it
            new EntEffects = GetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects");
            EntEffects |= EF_NODRAW;
            SetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects", EntEffects);
            
            IsCustom[client] = false;
        }
    }
    else
    {
        if (IsCustom[client])
        {
            //copy the animation stuff from the viewmodel to the used one every frame
            SetEntProp(ClientVM[client][1], Prop_Send, "m_nSequence", GetEntProp(ClientVM[client][0], Prop_Send, "m_nSequence"));
            SetEntPropFloat(ClientVM[client][1], Prop_Send, "m_flPlaybackRate", GetEntPropFloat(ClientVM[client][0], Prop_Send, "m_flPlaybackRate"));
            
            if ((Cycle < OldCycle[client]) && (Sequence == OldSequence[client]))
            {
                SetEntProp(ClientVM[client][1], Prop_Send, "m_nSequence", 0);
            }
        }
    }
    //hide viewmodel a frame after spawning
    if (SpawnCheck[client])
    {
        SpawnCheck[client] = false;
        if (IsCustom[client])
        {
            new EntEffects = GetEntProp(ClientVM[client][0], Prop_Send, "m_fEffects");
            EntEffects |= EF_NODRAW;
            SetEntProp(ClientVM[client][0], Prop_Send, "m_fEffects", EntEffects);
        }
    }
    
    OldWeapon[client] = WeaponIndex;
    OldSequence[client] = Sequence;
    OldCycle[client] = Cycle;
}
//hide viewmodel on death
public Event_PlayerDeath(Handle:event, const String:name[], bool:dontBroadcast)
{
    new UserId = GetEventInt(event, "userid");
    new client = GetClientOfUserId(UserId);
    
    new EntEffects = GetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects");
    EntEffects |= EF_NODRAW;
    SetEntProp(ClientVM[client][1], Prop_Send, "m_fEffects", EntEffects);
}

//when a player repsawns at round start after surviving previous round the viewmodel is unhidden
public Event_PlayerSpawn(Handle:event, const String:name[], bool:dontBroadcast)
{
    new UserId = GetEventInt(event, "userid");
    new client = GetClientOfUserId(UserId);
    
    //use to delay hiding viewmodel a frame or it won't work
    SpawnCheck[client] = true;
    
    // WorldModel
    new ActiveWeapon = GetEntPropEnt(client, Prop_Data, "m_hActiveWeapon");
    if(ActiveWeapon != -1)
    {
        CreateTimer(0.1, ChangeModelIndex, client);
    }
    return Plugin_Continue;
}  

public Action:WeaponHook(Client, weapon)
{
    new ActiveWeapon = GetEntPropEnt(Client, Prop_Data, "m_hActiveWeapon");
    if(ActiveWeapon != -1)
    {
        CreateTimer(0.1, ChangeModelIndex, Client);
    }
    return Plugin_Continue;
}

public Action:ChangeModelIndex(Handle:Timer, any:Client)
{
    new ActiveWeapon = GetEntPropEnt(Client, Prop_Data, "m_hActiveWeapon");
    
    decl String:sWeapon[64];
    GetEdictClassname(ActiveWeapon, sWeapon, sizeof(sWeapon));
    if(StrEqual(sWeapon, "weapon_mp5navy"))
    {
        SetEntProp(ActiveWeapon, Prop_Send, "m_iWorldModelIndex", CustomWorldModel1);
    }
    if(StrEqual(sWeapon, "weapon_ump45"))
    {
        SetEntProp(ActiveWeapon, Prop_Send, "m_iWorldModelIndex", CustomWorldModel2);
    }
}

Please note, this is not my code.

I'm simply posting it in hope for more possibilities to occur in the limited world of CS:S coding.

I have attempted to recomplie a M4, failiure. However this does work with custom knife models and such. Although it needs tweaking for that.

[Mitchell]

Oh cool code, i also found something very very similar... like it's in the tutorial / snippet sections of THIS forum!
https://forums.alliedmods.net/showthread.php?t=181558

[Franc1sco]

Originally Posted by SkydiveX However this does work with custom knife models and such. Although it needs tweaking for that.

This subject interests me.

Only with changing routes of gamebanana´s skins with StudioCompiler this should work? or to do something else more (in the skin)?

[SkydiveX]

I'm reposting this as it suddenly seems lost. Well done mitch for finding the post where I had got half of the code from. .

Anyway. The amazing thing is THIS WORKS. Think about the possibilities. If only I could recompile some weapon models, reskin them and create Golden Awp's e.t.c. I have attempted to, but no success.

[blodia]

i'll try and create a snippet/tutorial on how to create partially custom weapons when i have some time, i tested it 3-4 months ago and just haven't had the time to share it.

[Mitchell]

Originally Posted by blodia i'll try and create a snippet/tutorial on how to create partially custom weapons when i have some time, i tested it 3-4 months ago and just haven't had the time to share it.

Yeah, it would be better to actually have it re-coded since now with the world model is looks pretty bad lol.

[SkydiveX]

Yep. It looks bad mainly because its the model on a different weapon. it would be flawless using a custom model designed for the weapon itself.
Using SDK hooks to edit its damage values.
weapon_fire event.
Grenade Touch Explode.
now you have a lovely grenade launcher, eh????

I miss the old days of 1.6 where you could EAISLY create new weapons.
Not sure why this is not possible in source or why it shouldn't be implemented?

[SkydiveX]

Originally Posted by blodia i'll try and create a snippet/tutorial on how to create partially custom weapons when i have some time, i tested it 3-4 months ago and just haven't had the time to share it.

Please Do. . Also could you show us how to recompile a weapon model to change its skin?

[Mitchell]

Originally Posted by SkydiveX Yep. It looks bad mainly because its the model on a different weapon

i was talking about the code

[SkydiveX]

Oh, Lmao . Found it on an ancient thread, . A few months ago I did optimize the code but lost the changes I had made due to other projects. R.I.P.